CheckBox

Define and Properties

Properties	Status
Properties	Default	Planned	Started	Ready	Comments
CREATE CHECKBOX cName \| (cVarName) \| &(cExpression)
[ ; OF cWindow \| (cVarName) \| &(cExpression) ]	Parent.Name				A reference to the Parent Window
[ ROW nRow ]	0				Row position on container window in pixels coordinates
[ COL nCol ]	0				Col position on container window in pixels coordinates
[ WIDTH nWidth ]	?				The desired width size of the Control in pixels
[ HEIGHT nHeight ]	?				The desired height size of the Control in pixels
[ ROWBOTTOM nRow ]	n/a				Bottom Row position on container window in pixels coordinates. This property adjust the HEIGHT property according the ROW property.
[ COLRIGHT nCol ]	n/a				Right Col position on container window in pixels coordinates. This property adjust the WIDTH property according the COL property.
[ ENABLED .T. \| .F. ]	.T.				Enable or Disable control
[ CAPTION cCaption ]	NIL				A text expressions for the control
[ AUTOSIZE .T. \| .F. ]	.F.				Auto adjust control size to text
[ FONTNAME "cFontName" ]	Parent.Fontname				Font family for control text
[ FONTSIZE nPoints ]	Parent.FontSize				Font size for control text
[ FONTBOLD .T. \| .F. ]	.F.				Set Bold attribute to control text
[ FONTITALIC .T. \| .F. ]	.F.				Set Italic attribute to control text
[ FONTUNDERLINE .T. \| .F. ]	.F.				Set Underline attribute to control text
[ FONTSTRIKEOUT .T. \| .F. ]	.F.				Set Strikeout attribute to control text
[ TRANSPARENT .T. \| .F. ]	.T.				Don't fill background control, set Transparent attibute
[ FONTCOLOR {aFontColor} \| aVarFontColor ]	OS.FontColor				Set foreground color (text color)
[ BACKCOLOR {aBackColor} \| aVarBackColor ]	OS.BackColor				Set background color
[ TOOLTIP cToolTip ]	NIL				Text for display into tooltip
[ PARENT cControlParent ]					Get or Set the control name of parent widget
[ PARENTTYPE n/a ]					Only for mg_get() function, this property returns the PARENT control type or "" if the parent was not set.
[ ALIGN nAlign ]	Qt_AlignLeft				Align text, most common value are Qt_AlignLeft , Qt_AlignCenter and Qt_AlignRight
[ VALUE bValue \| nValue ]	.F. \| 0				Control value, if THREESTATE is .T., VALUE accept 0, 1 and 2. If THREESTATE is .F., VALUE accept .T. and. .F.
[ THREESTATE .T. \| .F. ]	.F.				Control accept three values: 0, 1 and 2
[ NOTABSTOP .T. \| .F. ]	.F.				This property force that TAB key doesn't stop in this control
[ HASFOCUS ]	NIL				Only for mg_Get() function. This property returns .T. if control has the application focus
[ CURSOR ]	Qt_ArrowCursor				Change the cursor pointer shape for the control. Go to to learn more about it.
[ PERMANENT .T. \| .F. ]	.F.				Only for controls defined into STATUSBAR. This property force this control as permanent statusbar message. Control will be placed at right corner of statusbar and it is never hidden. Used for important mode indications, for example, some applications put a Caps Lock indicator in the status bar.
[ FORCEACTION .T. \| .F. ]	.F.				It force the execution of the actions defined by methods like ACTION, ONENTER, ONCLICK, ONDBLCLICK, etc. when NOTABSTOP property was set '.T.'. This property is useful when application focus is over a control when a VALID clause and it doesn't permit lostfocus.
[ ONCHANGE cOnChange \| {BOnChange} ]	NIL				An action to be performed when control value is changed
[ ONGOTFOCUS cOnGotFocus \| {BOnGotFocus} ]	NIL				An action to be performed when control is focused
[ ONLOSTFOCUS cOnLostFocus \| {BOnLostFocus} ]	NIL				An action to be performed when control is lost focused
[ VISIBLE .T. \| .F. ]	.T.				Show or hide control (like methods SHOW and HIDE)
[ CREATE CONTEXT MENU [ cName ] ]					CONTEXT MENU for control
[ ......... ]					You can see properties for this menu in CONTEXT MENU topic
[ END MENU ]
END CHECKBOX

Jump to Context Menu topic

Methods

Methods	Status
Methods	Default	Planned	Started	Ready	Comments
HIDE	n/a				This method HIDE the control
SHOW	n/a				This method SHOW the control
UNSETCURSOR	n/a				Reset the cursor pointer shape for the control to default (Qt_ArrowCursor). Go to to learn more about it.
RELEASE	n/a				This method is used to destroy the control.
SETFOCUS	n/a				This method put the program focus into control
ONCHANGE	n/a				Execute ONCHANGE block coded in CREATE or seted by mg_Set
ONGOTFOCUS	n/a				Execute ONGOTFOCUS block coded in CREATE or seted by mg_Set
ONLOSTFOCUS	n/a				Execute ONLOSTFOCUS block coded in CREATE or seted by mg_Set

Example:

File: d_checkbox.prg

#include "marinas-gui.ch"

MEMVAR cCheckboxName
MEMVAR nNumber

Function main()

   PRIVATE cCheckboxName := "d_checkbox"
   PRIVATE nNumber     := 33

   SET APPLSTYLE TO "MarinasLooks"

   CREATE WINDOW d_window
      ROW 0 ; COL 0
      WIDTH 820 ; HEIGHT 480
      CAPTION "Marinas-GUI Sample for Checkbox Control"
      ICON "../resource/d_test.ico"
      BACKCOLOR {216,237,236}
      MAIN .T.

      d_checkbox_def()

   END WINDOW

   mg_Do( "d_window" , "center" )

   mg_Do( "d_window" , "activate" )

Return .T.

File: d_checkbox_def.prg

#include "marinas-gui.ch"

Function d_checkbox_def()

      CREATE CHECKBOX Check_1
             ROW    60
             COL    140
             WIDTH  178
             HEIGHT 29
             VALUE .T.
             CAPTION "CheckBox with BackColor"
             TOOLTIP "Tooltip for CheckBox with onChange property"
             BACKCOLOR {0,255,0}
             FONTCOLOR {0,0,255}
             ONCHANGE mg_Set( "d_window" , "check_1Label" , "value" , "CheckBox has set to: " + mg_AllStr( mg_Get( "d_window" , "Check_1" , "value" ) ) )

             CREATE CONTEXT MENU

                CREATE ITEM "Item 1 from CheckBox"
                   ONCLICK { || mg_MsgInfo( "Item 1 from CheckBox" ) }
                   PICTURE "../resource/d_test.png"
                END ITEM

                CREATE ITEM "Item 2 from CheckBox"
                   ONCLICK { || mg_MsgInfo( "Item 2 from CheckBox" ) }
                   PICTURE "../resource/d_test.png"
                END ITEM

             END MENU

      END CHECKBOX

      CREATE LABEL Check_1Label
             ROW    60
             COL    330
             WIDTH  178
             HEIGHT 29
             VALUE "CheckBox has set to: " + mg_AllStr( mg_Get( "d_window" , "Check_1" , "value" ) )
             FONTCOLOR {0,0,255}
             FONTBOLD .T.
      END LABEL

      CREATE CHECKBOX &( M->cCheckboxName + "__" + alltrim( str( M->nNumber ) ) )
             ROW    160
             COL    140
             AUTOSIZE .T.
             FONTBOLD .T.
             CAPTION "Autosize, FontBold and NoTransparent"
             VALUE .F.
             TOOLTIP "Tooltip for CheckBox"
             TRANSPARENT .F.
             ONGOTFOCUS mg_Set( "d_window" , M->cCheckboxName + "__" + alltrim( str( M->nNumber ) ) + "Label" , "value" , "Focused !!!" )
             ONLOSTFOCUS mg_Set( "d_window" , M->cCheckboxName + "__" + alltrim( str( M->nNumber ) ) + "Label" , "value" , "Without focus" )
      END CHECKBOX

      CREATE LABEL &( M->cCheckboxName + "__" + alltrim( str( M->nNumber ) ) + "Label" )
             ROW    155
             COL    420
             WIDTH  178
             HEIGHT 29
             VALUE "Without focus"
             FONTCOLOR {0,0,255}
             FONTBOLD .T.
      END LABEL

      CREATE CHECKBOX Check_3
             ROW    260
             COL    140
             AUTOSIZE .T.
             CAPTION "ThreeState and Underline"
             TOOLTIP "Tooltip for CheckBox"
             VALUE 1
             THREESTATE .T.
             FONTUNDERLINE .T.
             ONCHANGE mg_Set( "d_window" , "check_3Label" , "value" , "CheckBox has set to: " + mg_AllStr( mg_Get( "d_window" , "Check_3" , "value" ) ) )
      END CHECKBOX

      CREATE LABEL Check_3Label
             ROW    260
             COL    330
             WIDTH  178
             HEIGHT 29
             VALUE "CheckBox has set to: " + mg_AllStr( mg_Get( "d_window" , "Check_3" , "value" ) )
             FONTCOLOR {0,0,255}
             FONTBOLD .T.
      END LABEL

      CREATE CHECKBOX Check_4
             ROW    360
             COL    140
             AUTOSIZE .T.
             FONTCOLOR {255,0,0}
             CAPTION "FontColor, FontSize"
             FONTSIZE 14
             TOOLTIP "Tooltip for CheckBox"
      END CHECKBOX

Return .T.

Marinas-GUI Version 03.06 and
Marinas-IDE Version 05.06 and
LEX Files Version 02.06

---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
last update: April 27
2017
---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------

A Harbour/QT framework to make multiplatform programs

(©) Copyright 2009-2017 by Fernando Santolin (aka CarozoDeQuilmes)
CarozoDeQuilmes@gmail.com

2009-2017 Beta tester and full English translator: Bruno Luciani
Bruno.Luciani@gmail.com

2014-2015 Final English corrector: David Worboys
DavidWorboys@hotmail.com

---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------

www.marinas-gui.org

www.marinas-gui.org